OBS 없이 캡처보드+닌텐도 스위치 디스코드 소리 포함 화면 공유하기

OBS 없이 캡처보드+닌텐도 스위치 디스코드 소리 포함 화면 공유하기

AVerMedia StreamLine Mini+ GC311G2 캡처보드를 사용하면서,
OBS를 거치지 않고 화면과 소리를 함께 공유하는 방법을 정리했습니다.

 

기존 OBS 방식의 한계

OBS의 “가상 카메라(OBS Virtual Camera)” 기능은 영상만 출력하고 소리는 출력되지 않습니다.

 

즉, 디스코드 화면 공유 시 영상은 나오지만 소리는 들리지 않는 문제가 있습니다.

OBS로 이를 해결하려면 VCABLE로 가상장비를 만들고 디스코드에도 소리를 바꾸는 등 복잡한 작업을 진행해야 합니다.

이렇게 작업해도 원하는 형태로는 공유가 안됩니다.

디스코드 애플리케이션 공유

OBS로 번잡한 작업을 해야 하는 이유는 캡처 중인 화면을 별도의 프로세스로 생성하는 기능을 OBS가 지원하지 않기 때문입니다.

이 작업을 해줄 것이 "ffplay" 입니다.

FFplay란?

FFplay는 FFmpeg에 포함된 초경량 영상 재생기입니다.
그래픽 인터페이스(GUI)는 없지만, 실시간 캡처 입력을 거의 지연 없이 표시할 수 있습니다.

 

❌ MAC은 확인되지 않았습니다. 이번 내용은 Windows 전용입니다.

Builds - CODEX FFMPEG @ gyan.dev

1. 해당 링크에서 ffmpeg-git-full.7z 를 찾아 다운로드합니다.

2. 이후 원하는 경로에 압축을 해제한 뒤 저장된 경로를 복사해주세요.

3. 찾기 > 시스템 환경 변수 편집을 실행해주세요.

4. 환경 변수 > 사용자에 대한 사용자 변수에서 Path 선택 후 새로 만들기

5. 환경 변수 편집 창에 새로만들기로 아까 압축 해제한 경로에서 ffmpeg\bin 을 추가해주세요

환경 변수 편집

 

완료되었다면 cmd를 실행하여 다음 명령어를 입력합니다.

ffplay -version

다음처럼 출력되면 성공입니다. (안 나오면 환경변수 설정이 잘못된 것입니다.)

ffplay version 2025-11-06-git-222127418b-full_build-www.gyan.dev Copyright (c) 2003-2025 the FFmpeg developers
built with gcc 15.2.0 (Rev8, Built by MSYS2 project)
configuration: --enable-gpl --enable-version3 --enable-static --disable-w32threads --disable-autodetect --enable-cairo --enable-fontconfig --enable-iconv --enable-gnutls --enable-lcms2 --enable-libxml2 --enable-gmp --enable-bzlib --enable-lzma --enable-libsnappy --enable-zlib --enable-librist --enable-libsrt --enable-libssh --enable-libzmq --enable-avisynth --enable-libbluray --enable-libcaca --enable-libdvdnav --enable-libdvdread --enable-sdl2 --enable-libaribb24 --enable-libaribcaption --enable-libdav1d --enable-libdavs2 --enable-libopenjpeg --enable-libquirc --enable-libuavs3d --enable-libxevd --enable-libzvbi --enable-liboapv --enable-libqrencode --enable-librav1e --enable-libsvtav1 --enable-libvvenc --enable-libwebp --enable-libx264 --enable-libx265 --enable-libxavs2 --enable-libxeve --enable-libxvid --enable-libaom --enable-libjxl --enable-libvpx --enable-mediafoundation --enable-libass --enable-frei0r --enable-libfreetype --enable-libfribidi --enable-libharfbuzz --enable-liblensfun --enable-libvidstab --enable-libvmaf --enable-libzimg --enable-amf --enable-cuda-llvm --enable-cuvid --enable-dxva2 --enable-d3d11va --enable-d3d12va --enable-ffnvcodec --enable-libvpl --enable-nvdec --enable-nvenc --enable-vaapi --enable-libshaderc --enable-vulkan --enable-libplacebo --enable-opencl --enable-libcdio --enable-openal --enable-libgme --enable-libmodplug --enable-libopenmpt --enable-libopencore-amrwb --enable-libmp3lame --enable-libshine --enable-libtheora --enable-libtwolame --enable-libvo-amrwbenc --enable-libcodec2 --enable-libilbc --enable-libgsm --enable-liblc3 --enable-libopencore-amrnb --enable-libopus --enable-libspeex --enable-libvorbis --enable-ladspa --enable-libbs2b --enable-libflite --enable-libmysofa --enable-librubberband --enable-libsoxr --enable-chromaprint --enable-whisper

 

여기까지 완료되었다면 두 가지 방법이 있습니다.

 

1. 스크립트를 직접 수정하여 실행하기

@echo off
chcp 65001 >nul
setlocal enabledelayedexpansion

title Capture Board Selector
echo ===============================================
echo   Capture Board Selector
echo ===============================================

rem =================================================
rem 설정 영역 — 실행 전에 직접 수정하세요
rem =================================================
set "VIDEO=StreamLine Mini+ GC311G2"
set "AUDIO=HDMI(StreamLine Mini+ GC311G2)"
rem =================================================

rem ▷ ffplay.exe 경로 확인
where ffplay >nul 2>nul
if errorlevel 1 (
  echo [ERROR] ffplay.exe를 찾을 수 없습니다.
  echo ffplay.exe가 PATH에 등록되어 있지 않거나, ffmpeg\bin 폴더 안에 없습니다.
  echo -----------------------------------------------
  echo 현재 경로: %CD%
  echo -----------------------------------------------
  pause
  exit /b
)

echo.
echo [INFO] 현재 설정된 장치:
echo [INFO] VIDEO = %VIDEO%
echo [INFO] AUDIO = %AUDIO%
echo.
echo ===============================================
rem ▷ 장치 목록 출력

echo.
echo [INFO] 장치 목록을 불러오는 중입니다...
ffmpeg -hide_banner -list_devices true -f dshow -i dummy > "%temp%\devicelist.txt" 2>&1

echo.
echo ===============================================
echo 비디오 장치 목록
echo ===============================================

for /f "tokens=2 delims=]" %%A in ('findstr /I " (video)" "%temp%\devicelist.txt"') do (
  set "line=%%A"
  set "line=!line:(video)=!"
  set "line=!line:"=!"
  set "line=!line: =!"
  echo !line!
)

echo.
echo ===============================================
echo 오디오 장치 목록
echo ===============================================

for /f "tokens=2 delims=]" %%A in ('findstr /I " (audio)" "%temp%\devicelist.txt"') do (
  set "line=%%A"
  set "line=!line:(audio)=!"
  set "line=!line:"=!"
  set "line=!line: =!"
  echo !line!
)

rem ▷ 장치 존재 여부 확인
findstr /C:"%VIDEO%" "%temp%\devicelist.txt" >nul
if errorlevel 1 (
  echo [ERROR] 비디오 장치 "%VIDEO%" 를 찾을 수 없습니다.
  echo 장치 이름을 위 목록에서 확인 후 다시 설정하세요.
  echo -----------------------------------------------
  pause
  exit /b
)

findstr /C:"%AUDIO%" "%temp%\devicelist.txt" >nul
if errorlevel 1 (
  echo [ERROR] 오디오 장치 "%AUDIO%" 를 찾을 수 없습니다.
  echo 장치 이름을 위 목록에서 확인 후 다시 설정하세요.
  echo -----------------------------------------------
  pause
  exit /b
)

echo [INFO] 장치 확인 완료!
echo -----------------------------------------------

ffplay -hide_banner -loglevel error -f dshow ^
 -fflags nobuffer ^
 -flags low_delay ^
 -avioflags direct ^
 -rtbufsize 512M ^
 -use_wallclock_as_timestamps 1 ^
 -audio_buffer_size 50 ^
 -async 1 ^
 -af "aresample=resampler=soxr:osf=s32:async=1:min_comp=0.001:first_pts=0" ^
 -i video="%VIDEO%":audio="%AUDIO%" ^
 -video_size 1920x1080 ^
 -vf scale=1920:1080,setdar=16/9 ^
 -window_title "Preview" ^
 -x 1920 -y 1080 ^
 -af "adelay=0|0"


echo -----------------------------------------------
echo [INFO] 프로그램이 종료되었습니다.
pause
endlocal

 

2. 프로그램으로 실행하기

CaptureBoardSelector.zip

1.58MB

 

프로그램 실행 시 동작 모습